Landry 2/20 Breakout

Dave Landry first described his 2/20 day breakout system in the December 1996 issue of Stocks & Commoditites Magazine (TASC). It is also covered in his book Dave Landry On Swing Trading. (purchase it below or one of Dave's other books) The set up requires today's and yesterday's low to have been above the 20 day exponential moving average (DEMA). Obviously you want the scan to present stocks for the first day this is true, so I have added a line that includes the requirement that two days ago the low had to be below the 20 DEMA. I have also added the restriction that the stock must have closed two days ago at or above $10. You may want to delete this, or add a volume restriction, also. The output format is my own based on what I like to look at.

The entry point is described as 10 ticks above the two day high. TASC defines a tick as the smallest increment that an issue trades in. Back when their article was written, this was 1/8's for stocks, so ten ticks would have been 1.25 above the two day high. Today we trade in decimals, so you can decide where you want to place your buy stop order.

The exit is just the opposite, using the 20 DEMA as a trailing stop. After two days when the low is below the 20 DEMA, the exit becomes 10 ticks below the low of those two days. Again, pick you definition of "ticks".

Output = "LAN220L.lst";
issuetype=common;
exchange nyse,nasdaq,amex;
daystoload=300;
DaysRequired=300;

Printhdrln "Symb,Close,QRS,30 Avg Vol,Vol,PE,IRLGroup,SharesFloat,Name,SharesShort(Mil),Short Interest,";

if Low(0) > EMovAvg(0,20,cl)  and 
Low(-1) > EMovAvg(-1,20,cl)  and 
Low(-2) < EMovAvg(-2,20,cl)  and
Close(-2) => 10 
then

println Symbol,",",Close(0):7:2,",",QRS(0):3:0,",",avgvol(0,-29):8:0,",",
vol(0):8:0,",",PE:5:0,",",IRLsymbol:12,",",Sharesfloat:5:1,",",Shortint:5:3;
endif;

Download LAN220L.EXP (Landry 2/20 Day Breakout Scan)

Landry Bow Tie

Looks for stocks that are undergoing a trend reversal based on Dave Landry's definition of a trend using his Bow Tie moving average pattern. Seeks to catch the stocks on the first day of the trend change. I have added my own output formatting to the scan plus the filtering of the UnRuly Dog 5-5-50 prescan, using it as the input file. Use of this scan in Swing Trading is covered in much more detail in Landry's book, Dave Landry on Swing Trading, available above.  This scan only detects the last crosser for a correct set up, so you will have to look through charts of the results to verify it is the "real deal".

input="udu5550.lst";
output = "bowtie.lst";
Exchange = NYSE , AMEX , NASDAQ;

DaysToLoad = 250;
Daysrequired=250;


Printhdrln "Symbol,Close,EPSRank,QRS,30adv,Vol,PE,IRLGroup,SharesFloat,Name,SharesShort";
if  (MovAvg(0,10,cl) > EMovAvg(0,20,cl) ) and
(EMovAvg(0,20,cl) > EMovAvg(0,30,cl) ) and
 (MovAvg(-1,10,cl) < EMovAvg(-1,20,cl) ) then
  println Symbol,",",Close(0):7:2,",",EPSRank(0):3:0,",",QRS(0):3:0,",",avgvol(0,-29):8:0,",",vol(0):8:0,
",",PE:5:0,",",IRLsymbol:12,",",Sharesfloat:5:1,",",description:-15,",",Shortint:5:3;
 endif;

Download LANBOWTIE.EXP (Landry Bow Tie Breakout Scan)

Linda's Full Bow Tie

The below scan is another variation of the Bow Tie. It provides for a more complete set up, and then change in the line up of the moving averages. It was written by Linda Eberz who is familiar to those around Quotes Plus bulletin boards, and includes her own variation of replacing the 10 SMA with a 10 EMA. She is one of two Scan Wizards that I know. Questions?... E-mail - "LindaP257@adelphia.net".

This scan produces a smaller list of stocks and you don't have to pour over the charts of the results to see if the pre crossover pattern is correct. The way the input list is generated is also different. It uses the HGSI filter function to produce the btfilter.lst file. Your HGSI list file should look like this:

After you have run this filter and the results are output to the "btfilter.lst" file, you are ready to run the scan.

Stocks with a "Set" code have a proper set up of the moving averages in a down trend and could be placed on a watch list. Stocks with a "hit" code mean that all the criteria have been met so one only needs to await the price move through the buy point.

Input="btfilter.lst;
Output="FullBT.lst";
 
Daystoload=250;
Daysrequired=250;
 
Printhdrln "Symb,Code,BuyPoint,Group,MktCap";
 
Float A,B;
String Code;
 
A:=0;
B:=0;
 
Code:=" ";
 
If EMovAvg(-6,20,CL) < EMovAvg(-6,30,CL) then
    If EMovAvg(-6,20,CL) > MovAvg(-6,10,CL) then
        If EMovAvg(0,20,CL) > EMovAvg(0,30,CL) then
            If EMovAvg(0,20,CL) < MovAvg(0,10,CL) then
                Code:="Set";
                B:=1;
            endif;
        endif;
    endif;
endif;
 
If B=1 then
    If Low (0)< Low(-1) then
        Code:="Hit";
        A:=1;
    endif;
endif;
 
If A+B=2 then
    Println Symbol,",",Code,",",(High(0)+.0625):0:2,",",IndustryGroup,",",MarketCap:0:1;
endif;
If B=1 then
    If A=0 then 
        Println Symbol,",",Code,",,",IndustryGroup,",",MarketCap:0:1;
    endif;
endif;

Download FULLBT.EXP (Linda's Full Bow Tie Scan)

Linda Bradford Raschke 80 - 20

Linda Bradford Raschke is one of the Market Wizards covered in Jack D. Schwager's book, The New Market Wizards - Conversations with America's Top Traders. Over the last ten years she has been a frequent featured speaker at our Society of Market Technicians meetings, always speaking to a packed house. She maintains a web site that is extremely helpful in assisting short term traders, LBR Group.com. In her book, Street Smarts, with Larry Conners, she describes the 80 - 20 set up as an outgrowth of market rhythm as described by The Taylor Trading Technique and additional work done by Steve Moore to take advantage of midday reversals within this rhythmic cycle.

The scan is for day traders and looks for stocks that opened in the top 20% of their daily range and closed in the bottom 20% of their daily range. I have again added my UnRuly Dog 5-5-50 pre-scan as the input file and formatted the output to my liking. You can omit the input file and change the scan internal price and volume restrictions to your own preferences. You can also reverse the scan for short trades.

All of the above mentioned books can be purchased below.

 Input= "udu5550.lst";
output = "LBR8020.lst";
daystoload=261;
DaysRequired=261;

Printhdrln "Symbol,Close,EPSRank,QRS,30adv,Vol,PE,IRLGroup,SharesFloat,SharesShort,Name,InstHold";
if Open(0) >= High(0)-(.2*Range(0))  and
Close(0) <= High(0)-(.8*Range(0)) and
Vol(0)>=500000 and
Close(0)>=7  
then
  println Symbol,",",Close(0):7:2,",",EPSRank(0):3:0,",",QRS(0):3:0,",",avgvol(0,-29):8:0,",",vol(0):8:0,
  ",",PE:5:0,",",IRLsymbol:12,",",Sharesfloat:5:2,",",Shortint:5:2,",",description:-15,",",InstHold:3:2;
 endif;

Download LBR8020L.EXP (LBR 80/20 Long Scan)

Linda Bradford Raschke ANTI Long Scan

The scan seeks to identify long swing trade opportunities as defined by Linda Bradford Raschke in her book, Street Smarts, with Larry Connors. This stochastic and its use to identify retracement patterns, are covered in detail in Chapter 9, entitled, "The ANTI".

Using the %D to determine the longer term trend, the play is to buy the upturn in %K after %D is in an uptrend.

My scan attempts to get these plays on your radar screen before they trigger. It looks for an uptrend that has not topped out yet, hence the scan line looking for stocks with a %D under 80. It also looks for stocks where the %D today is higher  than it was yesterday, identifying where %D is in an uptrend. It also looks for stocks where the %K today is less than %K yesterday, the pull back. Lastly, it ensures the stochastics fast line (%K) is below the slow line (%D).

You can reduce the number of stocks in the output file by adding your own input file of favorite stocks.

Street Smarts can be purchased below.

 output="LBRAnti.lst";

issuetype=common;
exchange nyse,nasdaq,amex;

Set STOCHASTIC = 7,4,10;


If StochasticPctD(0)< 80 and 
StochasticPctD(-1) < StochasticPctD(0) and 
StochasticPctK(-1) > StochasticPctK(0) and 
StochasticPctK(0) < StochasticPctD(0) and 
Close (0) =>10 and
avgvol(0,-29)>50000 and // 30 day average volume greater than 50k per day
Close (0) < Close (-1) then
 println Symbol,",",Close(0):7:2,",",EPSRank(0):3:0,",",QRS(0):3:0,",",avgvol(0,-29):8:0,",",vol(0):8:0,",",
 PE:5:0,",",IRLsymbol:12,",",Sharesfloat:5:2,",",Shortint:5:2,",",description:-15,",",InstHold:3:2;
 endif;

Download LBRANTIL.EXP (LBR ANTI Long Scan)